автор перевода: Илья Михайлов	Предыдущая | Следующая | Оглавление

Camera.motionLevel

Доступность

Flash Player 6.

Синтаксис

active_cam.motionLevel:Number

Описание

Свойство только для чтения; числовое значение, которое определяет, насколько активным должно быть движение для вызова Camera.onActivity(true). Свойство может принять значения от 0 до 100. Значение по умолчанию равно 50.

Видео может быть показано независимо от значения свойства motionLevel. Чтобы получить дополнительную информацию, см. Camera.setMotionLevel().

Пример

В следующем примере непрерывно определяется активность движения в видеопотоке. Создайте новый экзэмпляр видео, выбрав New Video из меню настроек библиотеки (Library options menu). Добавьте экзэмпляр в сцену и дайте ему имя my_video. Добавьте экзэмпляр компонента Label в сцену и назовите его motionLevel_lbl. Добавьте экзэмпляр компонента NumericStepper в сцену и назовите его motionLevel_nstep. Затем добавьте экзэмпляр компонента ProgressBar в сцену и назовите его motion_pb. Скопируйте этот код в первый кадр таймлайна:

var my_cam:Camera = Camera.get();
var my_video:Video;
my_video.attachVideo(my_cam);

// configure the ProgressBar component instance
var motion_pb:mx.controls.ProgressBar;
motion_pb.mode = "manual";
motion_pb.label = "Motion: %3%%";

var motionLevel_lbl:mx.controls.Label;
// configure the NumericStepper component instance
var motionLevel_nstep:mx.controls.NumericStepper;
motionLevel_nstep.minimum = 0;
motionLevel_nstep.maximum = 100;
motionLevel_nstep.stepSize = 5;
motionLevel_nstep.value = my_cam.motionLevel;

/* Continuously update the progress of the ProgressBar component instance to the activityLevel of the current Camera instance, which is defined in my_cam */
this.onEnterFrame = function() {
  motion_pb.setProgress(my_cam.activityLevel, 100);
};

/* When the level of activity changes goes above or below the number defined in Camera.motionLevel, trigger the onActivity event handler. If the activityLevel is above the value defined in the motionLevel property isActive will be set to true. Otherwise, the activityLevel has fallen below the value defined in the motionLevel property (and stayed below that level for 2 seconds), so set the isActive parameter to false. */
my_cam.onActivity = function(isActive:Boolean) {
  /* If isActive equals true, set the themeColor variable to "haloGreen". 
     Otherwise set the themeColor to "haloOrange". */
  var themeColor:String = (isActive) ? "haloGreen" : "haloOrange";
  motion_pb.setStyle("themeColor", themeColor);
};

function changeMotionLevel() {
  /* Set the motionLevel property for my_cam Camera instance to the value of the NumericStepper component instance. Maintain the current motionTimeOut value of the my_cam Camera instance. */
  my_cam.setMotionLevel(motionLevel_nstep.value, my_cam.motionTimeOut);
}
motionLevel_nstep.addEventListener("change", changeMotionLevel);

См также

Camera.activityLevel, Camera.onActivity, Camera.onStatus, Camera.setMotionLevel()

Посмотреть комментарии LiveDocs		Предыдущая | Следующая | Оглавление